Master DevOps

Manchmal hat man Probleme ähnlich wie dieses hier: Man möchte nicht die gesuchte Zeile in einer Datei ausgeben, sondern die Zeile darüber. Und das Ganze soll mit einem Batch-Skript ausgeführt werden. Für dieses Problem habe ich mir einer Testdatei erstellt, die in etwas so aussieht:

123
abc
234
qwe
345
qwe
456
abc

Alle Zeilen, die über dem gesuchten String abc stehen, sollen ausgegeben werden, also

123
456

Das habe ich anschließend in einem Batch-Skript realisiert. Ich hoffe, die Kommentare hierfür sind ausreichend:

@echo off
SetLocal EnableDelayedExpansion

rem set initial values for the variables
set index=0
set "previous_line="
set "current_line="

rem Iterate over file, line by line
For /F "tokens=*" %%L in (array_data2.txt) do (
    set "previous_line=!current_line!"
    set "current_line=%%L"

    rem check if current line has searched
    string echo %%L| findstr /C:"abc" > nul

    rem if it has searched string, print previous
    rem and current line
    if not errorlevel 1 (
        echo !index!: !previous_line!
        set /a "curr_index=index+1"
        echo !curr_index!: !current_line!
        echo.
    )

    rem add 1 to the index
    set /a "index=index+1"
)

Quellen:

• https://www.tutorialspoint.com/batch_script/batch_script_arrays.htm
• https://stackoverflow.com/questions/10674974/calculating-the-sum-of-two-variables-in-a-batch-script
• https://stackoverflow.com/questions/13805187/how-to-set-a-variable-inside-a-loop-for-f/13805466

Dateien können verschiedene Kodierungen haben. Das Kommandozeilen-Werkzeug findstr kann in so einem Fall einen gesuchten String in einer Datei nicht finden. Ich hatte eine Datei, die hatte eine UCS-2 Kodierung und beim Aufruf von

findstr "abc" utc2.txt

kam nichts dabei heraus, obwohl die Textdatei diesen String enthielt. Um den gesuchten String trotzdem zu finden, kann man in so einem Fall auf das SysInternal Tools strings.exe zurückgreifen:

strings -nobanner utc2.txt | findstr "abc"

Ab und an sieht man im Internet Batch-Code, bei denen es um die Abfrage geht, ob der Errorlevel 0 oder ungleich 0 ist. Dabei sieht man Code-Zeilen, die in etwa so aussehen:

if errorlevel 0 (
   ...
) else (
   ...
)

Diese Abfrage ist aber in vielen Fällen falsch. Im Grunde bedeutet sie: Ist der Errorlevel 0 oder größer. D.h. diese Abfrage kommt fast gar nicht in den else-Teil, weil der Errorlevel meist 0 oder größer ist. Außer man hat ein Programm, welches negative Errorlevel zurückgibt.

Wenn man nun aber wissen möchte, ob der Errorlevel 1 oder größer ist, dann muss die Abfrage anders gestaltet werden:

if errorlevel 1 (
    ...
) else (
    ...
)

Man kann mit curl nur den Statuscode ausgeben lassen wenn man versucht sich mit einer Seite zu verbinden:

curl -s -o nul -w "%{http_code}" https://www.google.de

Bei einer Seite die nicht existiert bekommt man 000 als Statuscode zurück:

Mittels des Kommandos

dir /b "<Pfad>" 

kann man sich die Dateinamen in dem Ordner <Pfad> auflisten lassen. Also nur die Dateinamen, ohne den gesamten Pfadnamen und ohne sonstige Informationen. Nun war die Aufgabe nicht alle Dateinamen aufzulisten, sondern nur jene die eine bestimmte Endung hatten. Versucht habe ich dann erst einmal so:

dir /b "<Pfad>" *.cmd

Ich bekam eine Ausgabe, die mich etwas stutzig gemacht hat:

Woher kam die Meldung File not Found? Wie es sich herausgestellt hat, führt diese Art dir aufzurufen zu folgendem Verhalten: Zuerst werden alle Dateien in dem Ordner <Pfad> aufgelistet und dann alle *.cmd Dateien, die sich in dem Ordner befinden in dem ich mich gerade in der Konsole befinde. Und in diesem Beispiel war das eben der C:\ Ordner. Und weil ich in C:\ keine *.cmd Dateien hatte, hat dir mir die Fehlermeldung File not Found ausgegeben.

Um trotzdem alle Dateinamen mit bestimmter Endung in einem Ordner heraus zu finden, muss man das Kommando nur leicht abändern:

dir /b <Pfad> | findstr /R /C:"\.cmd$"

Mit dem Kommandowerkzeug findstr kann man unter Windows auf das letzte Zeichen eines Strings überprüfen. Eine Art dies zu bewerkstelligen kann man an folgendem Code sehen. Hier wird geprüft, ob die Variable %Project% mit einem Schrägstrich / endet oder nicht. Dabei wird ein Regex verwendet. Das Dollarzeichen in dem Regex steht hier für das Zeilenende, daher auch der “/$”:

@ECHO OFF
SETLOCAL EnableDelayedExpansion
SET "Project=/Folder1"
ECHO %Project%| findstr /R /C:"/$" 1>nul
echo %ERRORLEVEL%

SET "Project=/Folder1/"
ECHO %Project%| findstr /R /C:"/$" 1>nul
echo %ERRORLEVEL%

Bei diesem Code sollte man beachten, dass es kein Leerzeichen zwischen der Variablen %Project% und dem Pipelinezeichen | gibt. Gibt es ein Leerzeichen wird der gesamte Befehl missinterpretiert als würde das letzte Zeichen des Strings ein Leerzeichen sein und findstr gibt dann in beiden Fällen eine 1 zurück.